60205944bb
* Clean code - using type().interfaceId to improve readeability of ERC165 registration - hardcoding some keccak256 that are otherwise computed at construction. * hardcode keccak256 result * Improve code readeability using try/catch * Remove hardcoded hash tests show that solc 0.8.0 does the optimization as expected * Use try/catch to improve readability * ERC165Checker: Do not revert when returndata is empty + new test * Address PR comments * improve testing of ERC721Receiver errors * put back comment about invalid interface id * coverage does not support 0.8.1. Reverting back to 0.8.0 * bubble all data with length > 0 if onERC721Receive fails. * Fix test: revert without message trigger is bubble with the default message * using enum object to improve readability
50 lines
1.5 KiB
Solidity
50 lines
1.5 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
|
|
pragma solidity ^0.8.0;
|
|
|
|
import "./IERC165.sol";
|
|
|
|
/**
|
|
* @dev Implementation of the {IERC165} interface.
|
|
*
|
|
* Contracts may inherit from this and call {_registerInterface} to declare
|
|
* their support of an interface.
|
|
*/
|
|
abstract contract ERC165 is IERC165 {
|
|
/**
|
|
* @dev Mapping of interface ids to whether or not it's supported.
|
|
*/
|
|
mapping(bytes4 => bool) private _supportedInterfaces;
|
|
|
|
constructor () {
|
|
// Derived contracts need only register support for their own interfaces,
|
|
// we register support for ERC165 itself here
|
|
_registerInterface(type(IERC165).interfaceId);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC165-supportsInterface}.
|
|
*
|
|
* Time complexity O(1), guaranteed to always use less than 30 000 gas.
|
|
*/
|
|
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
|
|
return _supportedInterfaces[interfaceId];
|
|
}
|
|
|
|
/**
|
|
* @dev Registers the contract as an implementer of the interface defined by
|
|
* `interfaceId`. Support of the actual ERC165 interface is automatic and
|
|
* registering its interface id is not required.
|
|
*
|
|
* See {IERC165-supportsInterface}.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `interfaceId` cannot be the ERC165 invalid interface (`0xffffffff`).
|
|
*/
|
|
function _registerInterface(bytes4 interfaceId) internal virtual {
|
|
require(interfaceId != 0xffffffff, "ERC165: invalid interface id");
|
|
_supportedInterfaces[interfaceId] = true;
|
|
}
|
|
}
|