d17ae0b806
* signed safe math * fix lint errors * refactor overflow checks and add descriptions * remove incorrect description * add test for reversed arguments in multiplication test * fix power operator * improve multiplication test descriptions * Update SafeMath.test.js * add feature to changelog
119 lines
3.4 KiB
Solidity
119 lines
3.4 KiB
Solidity
pragma solidity ^0.4.24;
|
|
|
|
/**
|
|
* @title SafeMath
|
|
* @dev Math operations with safety checks that revert on error
|
|
*/
|
|
library SafeMath {
|
|
int256 constant private INT256_MIN = -2**255;
|
|
|
|
/**
|
|
* @dev Multiplies two unsigned integers, reverts on overflow.
|
|
*/
|
|
function mul(uint256 a, uint256 b) internal pure returns (uint256) {
|
|
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the
|
|
// benefit is lost if 'b' is also tested.
|
|
// See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
|
|
if (a == 0) {
|
|
return 0;
|
|
}
|
|
|
|
uint256 c = a * b;
|
|
require(c / a == b);
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Multiplies two signed integers, reverts on overflow.
|
|
*/
|
|
function mul(int256 a, int256 b) internal pure returns (int256) {
|
|
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the
|
|
// benefit is lost if 'b' is also tested.
|
|
// See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
|
|
if (a == 0) {
|
|
return 0;
|
|
}
|
|
|
|
require(!(a == -1 && b == INT256_MIN)); // This is the only case of overflow not detected by the check below
|
|
|
|
int256 c = a * b;
|
|
require(c / a == b);
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Integer division of two unsigned integers truncating the quotient, reverts on division by zero.
|
|
*/
|
|
function div(uint256 a, uint256 b) internal pure returns (uint256) {
|
|
// Solidity only automatically asserts when dividing by 0
|
|
require(b > 0);
|
|
uint256 c = a / b;
|
|
// assert(a == b * c + a % b); // There is no case in which this doesn't hold
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Integer division of two signed integers truncating the quotient, reverts on division by zero.
|
|
*/
|
|
function div(int256 a, int256 b) internal pure returns (int256) {
|
|
require(b != 0); // Solidity only automatically asserts when dividing by 0
|
|
require(!(b == -1 && a == INT256_MIN)); // This is the only case of overflow
|
|
|
|
int256 c = a / b;
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Subtracts two unsigned integers, reverts on overflow (i.e. if subtrahend is greater than minuend).
|
|
*/
|
|
function sub(uint256 a, uint256 b) internal pure returns (uint256) {
|
|
require(b <= a);
|
|
uint256 c = a - b;
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Subtracts two signed integers, reverts on overflow.
|
|
*/
|
|
function sub(int256 a, int256 b) internal pure returns (int256) {
|
|
int256 c = a - b;
|
|
require((b >= 0 && c <= a) || (b < 0 && c > a));
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Adds two unsigned integers, reverts on overflow.
|
|
*/
|
|
function add(uint256 a, uint256 b) internal pure returns (uint256) {
|
|
uint256 c = a + b;
|
|
require(c >= a);
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Adds two signed integers, reverts on overflow.
|
|
*/
|
|
function add(int256 a, int256 b) internal pure returns (int256) {
|
|
int256 c = a + b;
|
|
require((b >= 0 && c >= a) || (b < 0 && c < a));
|
|
|
|
return c;
|
|
}
|
|
|
|
/**
|
|
* @dev Divides two unsigned integers and returns the remainder (unsigned integer modulo),
|
|
* reverts when dividing by zero.
|
|
*/
|
|
function mod(uint256 a, uint256 b) internal pure returns (uint256) {
|
|
require(b != 0);
|
|
return a % b;
|
|
}
|
|
}
|