8fd072cf8e
* Added basic Escrow * PullPayment now uses an Escrow, removing all trust from the contract * Abstracted the Escrow tests to a behaviour * Added ConditionalEscrow * Added RefundableEscrow. * RefundableCrowdsale now uses a RefundEscrow, removed RefundVault. * Renaming after code review. * Added log test helper. * Now allowing empty deposits and withdrawals. * Style fixes. * Minor review comments. * Add Deposited and Withdrawn events, removed Refunded * The base Escrow is now Ownable, users of it (owners) must provide methods to access it.
73 lines
1.6 KiB
Solidity
73 lines
1.6 KiB
Solidity
pragma solidity ^0.4.24;
|
|
|
|
|
|
import "../../math/SafeMath.sol";
|
|
import "./FinalizableCrowdsale.sol";
|
|
import "../../payment/RefundEscrow.sol";
|
|
|
|
|
|
/**
|
|
* @title RefundableCrowdsale
|
|
* @dev Extension of Crowdsale contract that adds a funding goal, and
|
|
* the possibility of users getting a refund if goal is not met.
|
|
*/
|
|
contract RefundableCrowdsale is FinalizableCrowdsale {
|
|
using SafeMath for uint256;
|
|
|
|
// minimum amount of funds to be raised in weis
|
|
uint256 public goal;
|
|
|
|
// refund escrow used to hold funds while crowdsale is running
|
|
RefundEscrow private escrow;
|
|
|
|
/**
|
|
* @dev Constructor, creates RefundEscrow.
|
|
* @param _goal Funding goal
|
|
*/
|
|
constructor(uint256 _goal) public {
|
|
require(_goal > 0);
|
|
escrow = new RefundEscrow(wallet);
|
|
goal = _goal;
|
|
}
|
|
|
|
/**
|
|
* @dev Investors can claim refunds here if crowdsale is unsuccessful
|
|
*/
|
|
function claimRefund() public {
|
|
require(isFinalized);
|
|
require(!goalReached());
|
|
|
|
escrow.withdraw(msg.sender);
|
|
}
|
|
|
|
/**
|
|
* @dev Checks whether funding goal was reached.
|
|
* @return Whether funding goal was reached
|
|
*/
|
|
function goalReached() public view returns (bool) {
|
|
return weiRaised >= goal;
|
|
}
|
|
|
|
/**
|
|
* @dev escrow finalization task, called when owner calls finalize()
|
|
*/
|
|
function finalization() internal {
|
|
if (goalReached()) {
|
|
escrow.close();
|
|
escrow.beneficiaryWithdraw();
|
|
} else {
|
|
escrow.enableRefunds();
|
|
}
|
|
|
|
super.finalization();
|
|
}
|
|
|
|
/**
|
|
* @dev Overrides Crowdsale fund forwarding, sending funds to escrow.
|
|
*/
|
|
function _forwardFunds() internal {
|
|
escrow.deposit.value(msg.value)(msg.sender);
|
|
}
|
|
|
|
}
|