c05918c3cc
* Basic idea * Fine tuning idea * Add comments / tidy up Crowdsale base class * fixed TimedCrowdsale constructor * added simple crowdsale test * added HODL directory under home to store unused contracts. ugly hack to solve Crowdsale selection in tests, better way? * Capped no longer inherits from Timed, added capReached() method (replacing hasEnded()) * added SafeMath in TimedCrowdsale for safety, CHECK whether it is inherited from Crowdsale * several fixes related to separating Capped from Timed. functions renamed, mocks changed. Capped tests passing * added TimedCrowdsaleImpl.sol, TimedCrowdsale tests, passed * added Whitelisted implementation and test, passed. * removed unnecessary super constructor call in WhitelistedCrowdsale, removed unused dependencies in tests * renamed UserCappedCrowdsale to IndividuallyCappedCrowdsale, implemented IndividuallyCappedCrowdsaleImpl.sol and corresponding tests, passed. * homogeneized use of using SafeMath for uint256 across validation crowdsales. checked that it IS indeed inherited, but leaving it there as per Frans suggestion. * adding questions.md where I track questions, bugs and progress * modified VariablePriceCrowdsale, added Impl. * finished VariablePrice, fixed sign, added test, passing. * changed VariablePrice to IncreasingPrice, added corresponding require() * MintedCrowdsale done, mock implemented, test passing * PremintedCrowdsale done, mocks, tests passing * checked FinalizableCrowdsale * PostDeliveryCrowdsale done, mock, tests passing. * RefundableCrowdsale done. Detached Vault. modified mock and test, passing * renamed crowdsale-refactor to crowdsale in contracts and test * deleted HODL old contracts * polished variable names in tests * fixed typos and removed comments in tests * Renamed 'crowdsale-refactor' to 'crowdsale' in all imports * Fix minor param naming issues in Crowdsale functions and added documentation to Crowdsale.sol * Added documentation to Crowdsale extensions * removed residual comments and progress tracking files * added docs for validation crowdsales * Made user promises in PostDeliveryCrowdsale public so that users can query their promised token balance. * added docs for distribution crowdsales * renamed PremintedCrowdsale to AllowanceCrowdsale * added allowance check function and corresponding test. fixed filename in AllowanceCrowdsale mock. * spilt Crowdsale _postValidatePurchase in _postValidatePurchase and _updatePurchasingState. changed IndividuallyCappedCrowdsale accordingly. * polished tests for linter, salve Travis * polished IncreasingPriceCrowdsale.sol for linter. * renamed and polished for linter WhitelistedCrowdsale test. * fixed indentation in IncreasingPriceCrowdsaleImpl.sol for linter * fixed ignoring token.mint return value in MintedCrowdsale.sol * expanded docs throughout, fixed minor issues * extended test coverage for IndividuallyCappedCrowdsale * Extended WhitelistedCrwodsale test coverage * roll back decoupling of RefundVault in RefundableCrowdsale * moved cap exceedance checks in Capped and IndividuallyCapped crowdsales to _preValidatePurchase to save gas * revert name change, IndividuallyCapped to UserCapped * extended docs. * added crowd whitelisting with tests * added group capping, plus tests * added modifiers in TimedCrowdsale and WhitelistedCrowdsale * polished tests for linter * moved check of whitelisted to modifier, mainly for testing coverage * fixed minor ordering/polishingafter review * modified TimedCrowdsale modifier/constructor ordering * unchanged truffle-config.js * changed indentation of visibility modifier in mocks * changed naming of modifier and function to use Open/Closed for TimedCrowdsale * changed ordering of constructor calls in SampleCrowdsale * changed startTime and endTime to openingTime and closingTime throughout * fixed exceeding line lenght for linter * renamed _emitTokens to _deliverTokens * renamed addCrowdToWhitelist to addManyToWhitelist * renamed UserCappedCrowdsale to IndividuallyCappedCrowdsale
53 lines
2.0 KiB
Solidity
53 lines
2.0 KiB
Solidity
pragma solidity ^0.4.18;
|
|
|
|
import "../validation/TimedCrowdsale.sol";
|
|
import "../../math/SafeMath.sol";
|
|
|
|
/**
|
|
* @title IncreasingPriceCrowdsale
|
|
* @dev Extension of Crowdsale contract that increases the price of tokens linearly in time.
|
|
* Note that what should be provided to the constructor is the initial and final _rates_, that is,
|
|
* the amount of tokens per wei contributed. Thus, the initial rate must be greater than the final rate.
|
|
*/
|
|
contract IncreasingPriceCrowdsale is TimedCrowdsale {
|
|
using SafeMath for uint256;
|
|
|
|
uint256 public initialRate;
|
|
uint256 public finalRate;
|
|
|
|
/**
|
|
* @dev Constructor, takes intial and final rates of tokens received per wei contributed.
|
|
* @param _initialRate Number of tokens a buyer gets per wei at the start of the crowdsale
|
|
* @param _finalRate Number of tokens a buyer gets per wei at the end of the crowdsale
|
|
*/
|
|
function IncreasingPriceCrowdsale(uint256 _initialRate, uint256 _finalRate) public {
|
|
require(_initialRate >= _finalRate);
|
|
require(_finalRate > 0);
|
|
initialRate = _initialRate;
|
|
finalRate = _finalRate;
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the rate of tokens per wei at the present time.
|
|
* Note that, as price _increases_ with time, the rate _decreases_.
|
|
* @return The number of tokens a buyer gets per wei at a given time
|
|
*/
|
|
function getCurrentRate() public view returns (uint256) {
|
|
uint256 elapsedTime = now.sub(openingTime);
|
|
uint256 timeRange = closingTime.sub(openingTime);
|
|
uint256 rateRange = initialRate.sub(finalRate);
|
|
return initialRate.sub(elapsedTime.mul(rateRange).div(timeRange));
|
|
}
|
|
|
|
/**
|
|
* @dev Overrides parent method taking into account variable rate.
|
|
* @param _weiAmount The value in wei to be converted into tokens
|
|
* @return The number of tokens _weiAmount wei will buy at present time
|
|
*/
|
|
function _getTokenAmount(uint256 _weiAmount) internal view returns (uint256) {
|
|
uint256 currentRate = getCurrentRate();
|
|
return currentRate.mul(_weiAmount);
|
|
}
|
|
|
|
}
|