5dfe7215a9
* Initial migration to Solidity 0.6.x - v3.0 first steps (#2063) * Initial migration, missing GSN, 721, 777 and Crowdsales. * Add _beforeTokenOperation and _afterTokenOperation. * Add documentation for hooks. * Add hooks doc * Add missing drafts * Add back ERC721 with hooks * Bring back ERC777 * Notes on hooks * Bring back GSN * Make functions virtual * Make GSN overrides explicit * Fix ERC20Pausable tests * Remove virtual from some view functions * Update linter * Delete examples * Remove unnecessary virtual * Remove roles from Pausable * Remove roles * Remove users of roles * Adapt ERC20 tests * Fix ERC721 tests * Add all ERC721 hooks * Add ERC777 hooks * Fix remaining tests * Bump compiler version * Move 721BurnableMock into mocks directory * Remove _before hooks * Fix tests * Upgrade linter * Put modifiers last * Remove _beforeTokenApproval and _beforeOperatorApproval hooks
32 lines
1.2 KiB
Solidity
32 lines
1.2 KiB
Solidity
pragma solidity ^0.6.0;
|
|
|
|
/**
|
|
* @dev These functions deal with verification of Merkle trees (hash trees),
|
|
*/
|
|
library MerkleProof {
|
|
/**
|
|
* @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
|
|
* defined by `root`. For this, a `proof` must be provided, containing
|
|
* sibling hashes on the branch from the leaf to the root of the tree. Each
|
|
* pair of leaves and each pair of pre-images are assumed to be sorted.
|
|
*/
|
|
function verify(bytes32[] memory proof, bytes32 root, bytes32 leaf) internal pure returns (bool) {
|
|
bytes32 computedHash = leaf;
|
|
|
|
for (uint256 i = 0; i < proof.length; i++) {
|
|
bytes32 proofElement = proof[i];
|
|
|
|
if (computedHash <= proofElement) {
|
|
// Hash(current computed hash + current element of the proof)
|
|
computedHash = keccak256(abi.encodePacked(computedHash, proofElement));
|
|
} else {
|
|
// Hash(current element of the proof + current computed hash)
|
|
computedHash = keccak256(abi.encodePacked(proofElement, computedHash));
|
|
}
|
|
}
|
|
|
|
// Check if the computed hash (root) is equal to the provided root
|
|
return computedHash == root;
|
|
}
|
|
}
|