3e6c86392c
Co-authored-by: github-actions <41898282+github-actions[bot]@users.noreply.github.com> Co-authored-by: github-actions[bot] <github-actions[bot]@users.noreply.github.com> Co-authored-by: Francisco Giordano <fg@frang.io> Co-authored-by: Ernesto García <ernestognw@gmail.com> Co-authored-by: renovate[bot] <29139614+renovate[bot]@users.noreply.github.com> Co-authored-by: Eric Lau <ericglau@outlook.com> Co-authored-by: Hadrien Croubois <hadrien.croubois@gmail.com>
71 lines
2.2 KiB
Solidity
71 lines
2.2 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/beacon/UpgradeableBeacon.sol)
|
|
|
|
pragma solidity ^0.8.20;
|
|
|
|
import {IBeacon} from "./IBeacon.sol";
|
|
import {Ownable} from "../../access/Ownable.sol";
|
|
|
|
/**
|
|
* @dev This contract is used in conjunction with one or more instances of {BeaconProxy} to determine their
|
|
* implementation contract, which is where they will delegate all function calls.
|
|
*
|
|
* An owner is able to change the implementation the beacon points to, thus upgrading the proxies that use this beacon.
|
|
*/
|
|
contract UpgradeableBeacon is IBeacon, Ownable {
|
|
address private _implementation;
|
|
|
|
/**
|
|
* @dev The `implementation` of the beacon is invalid.
|
|
*/
|
|
error BeaconInvalidImplementation(address implementation);
|
|
|
|
/**
|
|
* @dev Emitted when the implementation returned by the beacon is changed.
|
|
*/
|
|
event Upgraded(address indexed implementation);
|
|
|
|
/**
|
|
* @dev Sets the address of the initial implementation, and the initial owner who can upgrade the beacon.
|
|
*/
|
|
constructor(address implementation_, address initialOwner) Ownable(initialOwner) {
|
|
_setImplementation(implementation_);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the current implementation address.
|
|
*/
|
|
function implementation() public view virtual returns (address) {
|
|
return _implementation;
|
|
}
|
|
|
|
/**
|
|
* @dev Upgrades the beacon to a new implementation.
|
|
*
|
|
* Emits an {Upgraded} event.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - msg.sender must be the owner of the contract.
|
|
* - `newImplementation` must be a contract.
|
|
*/
|
|
function upgradeTo(address newImplementation) public virtual onlyOwner {
|
|
_setImplementation(newImplementation);
|
|
}
|
|
|
|
/**
|
|
* @dev Sets the implementation contract address for this beacon
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `newImplementation` must be a contract.
|
|
*/
|
|
function _setImplementation(address newImplementation) private {
|
|
if (newImplementation.code.length == 0) {
|
|
revert BeaconInvalidImplementation(newImplementation);
|
|
}
|
|
_implementation = newImplementation;
|
|
emit Upgraded(newImplementation);
|
|
}
|
|
}
|