a7e91856f3
* Update to ganache-cli v6.1.0 and truffle v4.1.0 * Update to stable version of ganache-cli * fix: update event emission warning - Fix event emission warnings for solidity 4.21 after truffle has been updated to use this version * fix pr review comments * update to truffle v4.1.5 * update package-lock * add additional emit keywords * update solidity-coverage to 0.4.15 * update to solium 1.1.6 * fix MerkleProof coverage analysis by testing through wrapper * change version pragma to ^0.4.21 * fix solium linting errors
72 lines
1.7 KiB
Solidity
72 lines
1.7 KiB
Solidity
pragma solidity ^0.4.21;
|
|
|
|
import "../math/SafeMath.sol";
|
|
|
|
|
|
/**
|
|
* @title SplitPayment
|
|
* @dev Base contract that supports multiple payees claiming funds sent to this contract
|
|
* according to the proportion they own.
|
|
*/
|
|
contract SplitPayment {
|
|
using SafeMath for uint256;
|
|
|
|
uint256 public totalShares = 0;
|
|
uint256 public totalReleased = 0;
|
|
|
|
mapping(address => uint256) public shares;
|
|
mapping(address => uint256) public released;
|
|
address[] public payees;
|
|
|
|
/**
|
|
* @dev Constructor
|
|
*/
|
|
function SplitPayment(address[] _payees, uint256[] _shares) public payable {
|
|
require(_payees.length == _shares.length);
|
|
|
|
for (uint256 i = 0; i < _payees.length; i++) {
|
|
addPayee(_payees[i], _shares[i]);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev payable fallback
|
|
*/
|
|
function () public payable {}
|
|
|
|
/**
|
|
* @dev Claim your share of the balance.
|
|
*/
|
|
function claim() public {
|
|
address payee = msg.sender;
|
|
|
|
require(shares[payee] > 0);
|
|
|
|
uint256 totalReceived = this.balance.add(totalReleased);
|
|
uint256 payment = totalReceived.mul(shares[payee]).div(totalShares).sub(released[payee]);
|
|
|
|
require(payment != 0);
|
|
require(this.balance >= payment);
|
|
|
|
released[payee] = released[payee].add(payment);
|
|
totalReleased = totalReleased.add(payment);
|
|
|
|
payee.transfer(payment);
|
|
}
|
|
|
|
/**
|
|
* @dev Add a new payee to the contract.
|
|
* @param _payee The address of the payee to add.
|
|
* @param _shares The number of shares owned by the payee.
|
|
*/
|
|
function addPayee(address _payee, uint256 _shares) internal {
|
|
require(_payee != address(0));
|
|
require(_shares > 0);
|
|
require(shares[_payee] == 0);
|
|
|
|
payees.push(_payee);
|
|
shares[_payee] = _shares;
|
|
totalShares = totalShares.add(_shares);
|
|
}
|
|
}
|