3682c6575c
* Error handling in ERC20 and ERC721 * Added message string for require. * Fixed solhint errors. * Updated PR as per issue #1709 * changes as per #1709 and openzeppelin forum. * Changes in require statement * Changes in require statement * build pipeline fix * Changes as per @nventuro's comment. * Update revert reason strings. * Fianal update of revert reason strings. * WIP: Updating reason strings in test cases * WIP: Added changes to ERC20 and ERC721 * Fixes linting errors in *.tes.js files * Achieved 100% code coverage * Updated the test cases with shouldFail.reverting.withMessage() * Fix package-lock. * address review comments * fix linter issues * fix remaining revert reasons
93 lines
3.0 KiB
Solidity
93 lines
3.0 KiB
Solidity
pragma solidity ^0.5.7;
|
||
|
||
import "./ConditionalEscrow.sol";
|
||
|
||
/**
|
||
* @title RefundEscrow
|
||
* @dev Escrow that holds funds for a beneficiary, deposited from multiple
|
||
* parties.
|
||
* @dev Intended usage: See Escrow.sol. Same usage guidelines apply here.
|
||
* @dev The primary account (that is, the contract that instantiates this
|
||
* contract) may deposit, close the deposit period, and allow for either
|
||
* withdrawal by the beneficiary, or refunds to the depositors. All interactions
|
||
* with RefundEscrow will be made through the primary contract. See the
|
||
* RefundableCrowdsale contract for an example of RefundEscrow’s use.
|
||
*/
|
||
contract RefundEscrow is ConditionalEscrow {
|
||
enum State { Active, Refunding, Closed }
|
||
|
||
event RefundsClosed();
|
||
event RefundsEnabled();
|
||
|
||
State private _state;
|
||
address payable private _beneficiary;
|
||
|
||
/**
|
||
* @dev Constructor.
|
||
* @param beneficiary The beneficiary of the deposits.
|
||
*/
|
||
constructor (address payable beneficiary) public {
|
||
require(beneficiary != address(0), "RefundEscrow: beneficiary is the zero address");
|
||
_beneficiary = beneficiary;
|
||
_state = State.Active;
|
||
}
|
||
|
||
/**
|
||
* @return The current state of the escrow.
|
||
*/
|
||
function state() public view returns (State) {
|
||
return _state;
|
||
}
|
||
|
||
/**
|
||
* @return The beneficiary of the escrow.
|
||
*/
|
||
function beneficiary() public view returns (address) {
|
||
return _beneficiary;
|
||
}
|
||
|
||
/**
|
||
* @dev Stores funds that may later be refunded.
|
||
* @param refundee The address funds will be sent to if a refund occurs.
|
||
*/
|
||
function deposit(address refundee) public payable {
|
||
require(_state == State.Active, "RefundEscrow: can only deposit while active");
|
||
super.deposit(refundee);
|
||
}
|
||
|
||
/**
|
||
* @dev Allows for the beneficiary to withdraw their funds, rejecting
|
||
* further deposits.
|
||
*/
|
||
function close() public onlyPrimary {
|
||
require(_state == State.Active, "RefundEscrow: can only close while active");
|
||
_state = State.Closed;
|
||
emit RefundsClosed();
|
||
}
|
||
|
||
/**
|
||
* @dev Allows for refunds to take place, rejecting further deposits.
|
||
*/
|
||
function enableRefunds() public onlyPrimary {
|
||
require(_state == State.Active, "RefundEscrow: can only enable refunds while active");
|
||
_state = State.Refunding;
|
||
emit RefundsEnabled();
|
||
}
|
||
|
||
/**
|
||
* @dev Withdraws the beneficiary's funds.
|
||
*/
|
||
function beneficiaryWithdraw() public {
|
||
require(_state == State.Closed, "RefundEscrow: beneficiary can only withdraw while closed");
|
||
_beneficiary.transfer(address(this).balance);
|
||
}
|
||
|
||
/**
|
||
* @dev Returns whether refundees can withdraw their deposits (be refunded). The overridden function receives a
|
||
* 'payee' argument, but we ignore it here since the condition is global, not per-payee.
|
||
*/
|
||
function withdrawalAllowed(address) public view returns (bool) {
|
||
return _state == State.Refunding;
|
||
}
|
||
}
|