3682c6575c
* Error handling in ERC20 and ERC721 * Added message string for require. * Fixed solhint errors. * Updated PR as per issue #1709 * changes as per #1709 and openzeppelin forum. * Changes in require statement * Changes in require statement * build pipeline fix * Changes as per @nventuro's comment. * Update revert reason strings. * Fianal update of revert reason strings. * WIP: Updating reason strings in test cases * WIP: Added changes to ERC20 and ERC721 * Fixes linting errors in *.tes.js files * Achieved 100% code coverage * Updated the test cases with shouldFail.reverting.withMessage() * Fix package-lock. * address review comments * fix linter issues * fix remaining revert reasons
52 lines
1.3 KiB
Solidity
52 lines
1.3 KiB
Solidity
pragma solidity ^0.5.7;
|
|
|
|
import "../../math/SafeMath.sol";
|
|
import "../validation/TimedCrowdsale.sol";
|
|
|
|
/**
|
|
* @title FinalizableCrowdsale
|
|
* @dev Extension of TimedCrowdsale with a one-off finalization action, where one
|
|
* can do extra work after finishing.
|
|
*/
|
|
contract FinalizableCrowdsale is TimedCrowdsale {
|
|
using SafeMath for uint256;
|
|
|
|
bool private _finalized;
|
|
|
|
event CrowdsaleFinalized();
|
|
|
|
constructor () internal {
|
|
_finalized = false;
|
|
}
|
|
|
|
/**
|
|
* @return true if the crowdsale is finalized, false otherwise.
|
|
*/
|
|
function finalized() public view returns (bool) {
|
|
return _finalized;
|
|
}
|
|
|
|
/**
|
|
* @dev Must be called after crowdsale ends, to do some extra finalization
|
|
* work. Calls the contract's finalization function.
|
|
*/
|
|
function finalize() public {
|
|
require(!_finalized, "FinalizableCrowdsale: already finalized");
|
|
require(hasClosed(), "FinalizableCrowdsale: not closed");
|
|
|
|
_finalized = true;
|
|
|
|
_finalization();
|
|
emit CrowdsaleFinalized();
|
|
}
|
|
|
|
/**
|
|
* @dev Can be overridden to add finalization logic. The overriding function
|
|
* should call super._finalization() to ensure the chain of finalization is
|
|
* executed entirely.
|
|
*/
|
|
function _finalization() internal {
|
|
// solhint-disable-previous-line no-empty-blocks
|
|
}
|
|
}
|