ef347ffccc
* Consolidted ERC20 Interface and Implementation Files * Fixed CanReclaimToken's tests to use StandardTokenMock instead of BasicTokenMock * Changed token's variable type in TokenTimelock to ERC20 * Merged the StandardBurnableToken with BurnableToken since it now inherits from StandardToken; Fixed TokenTimelock so it uses SafeERC20 for ERC20 * Fixed variable type for _token in TokenTimelock constructor * Fixed linting warning in BurnableToken * Added back burnFrom tests.
45 lines
1.5 KiB
Solidity
45 lines
1.5 KiB
Solidity
pragma solidity ^0.4.24;
|
|
|
|
import "./StandardToken.sol";
|
|
|
|
|
|
/**
|
|
* @title Burnable Token
|
|
* @dev Token that can be irreversibly burned (destroyed).
|
|
*/
|
|
contract BurnableToken is StandardToken {
|
|
|
|
event Burn(address indexed burner, uint256 value);
|
|
|
|
/**
|
|
* @dev Burns a specific amount of tokens.
|
|
* @param _value The amount of token to be burned.
|
|
*/
|
|
function burn(uint256 _value) public {
|
|
_burn(msg.sender, _value);
|
|
}
|
|
|
|
/**
|
|
* @dev Burns a specific amount of tokens from the target address and decrements allowance
|
|
* @param _from address The address which you want to send tokens from
|
|
* @param _value uint256 The amount of token to be burned
|
|
*/
|
|
function burnFrom(address _from, uint256 _value) public {
|
|
require(_value <= allowed[_from][msg.sender]);
|
|
// Should https://github.com/OpenZeppelin/zeppelin-solidity/issues/707 be accepted,
|
|
// this function needs to emit an event with the updated approval.
|
|
allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
|
|
_burn(_from, _value);
|
|
}
|
|
|
|
function _burn(address _who, uint256 _value) internal {
|
|
require(_value <= balances[_who]);
|
|
// no need to require value <= totalSupply, since that would imply the
|
|
// sender's balance is greater than the totalSupply, which *should* be an assertion failure
|
|
|
|
balances[_who] = balances[_who].sub(_value);
|
|
totalSupply_ = totalSupply_.sub(_value);
|
|
emit Burn(_who, _value);
|
|
emit Transfer(_who, address(0), _value);
|
|
}
|
|
} |