5dfe7215a9
* Initial migration to Solidity 0.6.x - v3.0 first steps (#2063) * Initial migration, missing GSN, 721, 777 and Crowdsales. * Add _beforeTokenOperation and _afterTokenOperation. * Add documentation for hooks. * Add hooks doc * Add missing drafts * Add back ERC721 with hooks * Bring back ERC777 * Notes on hooks * Bring back GSN * Make functions virtual * Make GSN overrides explicit * Fix ERC20Pausable tests * Remove virtual from some view functions * Update linter * Delete examples * Remove unnecessary virtual * Remove roles from Pausable * Remove roles * Remove users of roles * Adapt ERC20 tests * Fix ERC721 tests * Add all ERC721 hooks * Add ERC777 hooks * Fix remaining tests * Bump compiler version * Move 721BurnableMock into mocks directory * Remove _before hooks * Fix tests * Upgrade linter * Put modifiers last * Remove _beforeTokenApproval and _beforeOperatorApproval hooks
74 lines
1.9 KiB
Solidity
74 lines
1.9 KiB
Solidity
pragma solidity ^0.6.0;
|
|
|
|
import "../GSN/Context.sol";
|
|
|
|
/**
|
|
* @dev Contract module which allows children to implement an emergency stop
|
|
* mechanism that can be triggered by an authorized account.
|
|
*
|
|
* This module is used through inheritance. It will make available the
|
|
* modifiers `whenNotPaused` and `whenPaused`, which can be applied to
|
|
* the functions of your contract. Note that they will not be pausable by
|
|
* simply including this module, only once the modifiers are put in place.
|
|
*/
|
|
contract Pausable is Context {
|
|
/**
|
|
* @dev Emitted when the pause is triggered by a pauser (`account`).
|
|
*/
|
|
event Paused(address account);
|
|
|
|
/**
|
|
* @dev Emitted when the pause is lifted by a pauser (`account`).
|
|
*/
|
|
event Unpaused(address account);
|
|
|
|
bool private _paused;
|
|
|
|
/**
|
|
* @dev Initializes the contract in unpaused state. Assigns the Pauser role
|
|
* to the deployer.
|
|
*/
|
|
constructor () internal {
|
|
_paused = false;
|
|
}
|
|
|
|
/**
|
|
* @dev Returns true if the contract is paused, and false otherwise.
|
|
*/
|
|
function paused() public view returns (bool) {
|
|
return _paused;
|
|
}
|
|
|
|
/**
|
|
* @dev Modifier to make a function callable only when the contract is not paused.
|
|
*/
|
|
modifier whenNotPaused() {
|
|
require(!_paused, "Pausable: paused");
|
|
_;
|
|
}
|
|
|
|
/**
|
|
* @dev Modifier to make a function callable only when the contract is paused.
|
|
*/
|
|
modifier whenPaused() {
|
|
require(_paused, "Pausable: not paused");
|
|
_;
|
|
}
|
|
|
|
/**
|
|
* @dev Called by a pauser to pause, triggers stopped state.
|
|
*/
|
|
function _pause() internal virtual whenNotPaused {
|
|
_paused = true;
|
|
emit Paused(_msgSender());
|
|
}
|
|
|
|
/**
|
|
* @dev Called by a pauser to unpause, returns to normal state.
|
|
*/
|
|
function _unpause() internal virtual whenPaused {
|
|
_paused = false;
|
|
emit Unpaused(_msgSender());
|
|
}
|
|
}
|