5dfe7215a9
* Initial migration to Solidity 0.6.x - v3.0 first steps (#2063) * Initial migration, missing GSN, 721, 777 and Crowdsales. * Add _beforeTokenOperation and _afterTokenOperation. * Add documentation for hooks. * Add hooks doc * Add missing drafts * Add back ERC721 with hooks * Bring back ERC777 * Notes on hooks * Bring back GSN * Make functions virtual * Make GSN overrides explicit * Fix ERC20Pausable tests * Remove virtual from some view functions * Update linter * Delete examples * Remove unnecessary virtual * Remove roles from Pausable * Remove roles * Remove users of roles * Adapt ERC20 tests * Fix ERC721 tests * Add all ERC721 hooks * Add ERC777 hooks * Fix remaining tests * Bump compiler version * Move 721BurnableMock into mocks directory * Remove _before hooks * Fix tests * Upgrade linter * Put modifiers last * Remove _beforeTokenApproval and _beforeOperatorApproval hooks
50 lines
2.0 KiB
Solidity
50 lines
2.0 KiB
Solidity
pragma solidity ^0.6.0;
|
|
|
|
/**
|
|
* @dev Helper to make usage of the `CREATE2` EVM opcode easier and safer.
|
|
* `CREATE2` can be used to compute in advance the address where a smart
|
|
* contract will be deployed, which allows for interesting new mechanisms known
|
|
* as 'counterfactual interactions'.
|
|
*
|
|
* See the https://eips.ethereum.org/EIPS/eip-1014#motivation[EIP] for more
|
|
* information.
|
|
*
|
|
* _Available since v2.5.0._
|
|
*/
|
|
library Create2 {
|
|
/**
|
|
* @dev Deploys a contract using `CREATE2`. The address where the contract
|
|
* will be deployed can be known in advance via {computeAddress}. Note that
|
|
* a contract cannot be deployed twice using the same salt.
|
|
*/
|
|
function deploy(bytes32 salt, bytes memory bytecode) internal returns (address) {
|
|
address addr;
|
|
// solhint-disable-next-line no-inline-assembly
|
|
assembly {
|
|
addr := create2(0, add(bytecode, 0x20), mload(bytecode), salt)
|
|
}
|
|
require(addr != address(0), "Create2: Failed on deploy");
|
|
return addr;
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the address where a contract will be stored if deployed via {deploy}. Any change in the `bytecode`
|
|
* or `salt` will result in a new destination address.
|
|
*/
|
|
function computeAddress(bytes32 salt, bytes memory bytecode) internal view returns (address) {
|
|
return computeAddress(salt, bytecode, address(this));
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the address where a contract will be stored if deployed via {deploy} from a contract located at
|
|
* `deployer`. If `deployer` is this contract's address, returns the same value as {computeAddress}.
|
|
*/
|
|
function computeAddress(bytes32 salt, bytes memory bytecodeHash, address deployer) internal pure returns (address) {
|
|
bytes32 bytecodeHashHash = keccak256(bytecodeHash);
|
|
bytes32 _data = keccak256(
|
|
abi.encodePacked(bytes1(0xff), deployer, salt, bytecodeHashHash)
|
|
);
|
|
return address(bytes20(_data << 96));
|
|
}
|
|
}
|