a7e91856f3
* Update to ganache-cli v6.1.0 and truffle v4.1.0 * Update to stable version of ganache-cli * fix: update event emission warning - Fix event emission warnings for solidity 4.21 after truffle has been updated to use this version * fix pr review comments * update to truffle v4.1.5 * update package-lock * add additional emit keywords * update solidity-coverage to 0.4.15 * update to solium 1.1.6 * fix MerkleProof coverage analysis by testing through wrapper * change version pragma to ^0.4.21 * fix solium linting errors
73 lines
1.6 KiB
Solidity
73 lines
1.6 KiB
Solidity
pragma solidity ^0.4.21;
|
|
|
|
|
|
import "../../math/SafeMath.sol";
|
|
import "./FinalizableCrowdsale.sol";
|
|
import "./utils/RefundVault.sol";
|
|
|
|
|
|
/**
|
|
* @title RefundableCrowdsale
|
|
* @dev Extension of Crowdsale contract that adds a funding goal, and
|
|
* the possibility of users getting a refund if goal is not met.
|
|
* Uses a RefundVault as the crowdsale's vault.
|
|
*/
|
|
contract RefundableCrowdsale is FinalizableCrowdsale {
|
|
using SafeMath for uint256;
|
|
|
|
// minimum amount of funds to be raised in weis
|
|
uint256 public goal;
|
|
|
|
// refund vault used to hold funds while crowdsale is running
|
|
RefundVault public vault;
|
|
|
|
/**
|
|
* @dev Constructor, creates RefundVault.
|
|
* @param _goal Funding goal
|
|
*/
|
|
function RefundableCrowdsale(uint256 _goal) public {
|
|
require(_goal > 0);
|
|
vault = new RefundVault(wallet);
|
|
goal = _goal;
|
|
}
|
|
|
|
/**
|
|
* @dev Investors can claim refunds here if crowdsale is unsuccessful
|
|
*/
|
|
function claimRefund() public {
|
|
require(isFinalized);
|
|
require(!goalReached());
|
|
|
|
vault.refund(msg.sender);
|
|
}
|
|
|
|
/**
|
|
* @dev Checks whether funding goal was reached.
|
|
* @return Whether funding goal was reached
|
|
*/
|
|
function goalReached() public view returns (bool) {
|
|
return weiRaised >= goal;
|
|
}
|
|
|
|
/**
|
|
* @dev vault finalization task, called when owner calls finalize()
|
|
*/
|
|
function finalization() internal {
|
|
if (goalReached()) {
|
|
vault.close();
|
|
} else {
|
|
vault.enableRefunds();
|
|
}
|
|
|
|
super.finalization();
|
|
}
|
|
|
|
/**
|
|
* @dev Overrides Crowdsale fund forwarding, sending funds to vault.
|
|
*/
|
|
function _forwardFunds() internal {
|
|
vault.deposit.value(msg.value)(msg.sender);
|
|
}
|
|
|
|
}
|