120 lines
4.9 KiB
Solidity
120 lines
4.9 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts v4.4.1 (utils/cryptography/draft-EIP712.sol)
|
|
|
|
pragma solidity ^0.8.0;
|
|
|
|
import "./ECDSAUpgradeable.sol";
|
|
import "../../proxy/utils/Initializable.sol";
|
|
|
|
/**
|
|
* @dev https://eips.ethereum.org/EIPS/eip-712[EIP 712] is a standard for hashing and signing of typed structured data.
|
|
*
|
|
* The encoding specified in the EIP is very generic, and such a generic implementation in Solidity is not feasible,
|
|
* thus this contract does not implement the encoding itself. Protocols need to implement the type-specific encoding
|
|
* they need in their contracts using a combination of `abi.encode` and `keccak256`.
|
|
*
|
|
* This contract implements the EIP 712 domain separator ({_domainSeparatorV4}) that is used as part of the encoding
|
|
* scheme, and the final step of the encoding to obtain the message digest that is then signed via ECDSA
|
|
* ({_hashTypedDataV4}).
|
|
*
|
|
* The implementation of the domain separator was designed to be as efficient as possible while still properly updating
|
|
* the chain id to protect against replay attacks on an eventual fork of the chain.
|
|
*
|
|
* NOTE: This contract implements the version of the encoding known as "v4", as implemented by the JSON RPC method
|
|
* https://docs.metamask.io/guide/signing-data.html[`eth_signTypedDataV4` in MetaMask].
|
|
*
|
|
* _Available since v3.4._
|
|
*/
|
|
abstract contract EIP712Upgradeable is Initializable {
|
|
/* solhint-disable var-name-mixedcase */
|
|
bytes32 private _HASHED_NAME;
|
|
bytes32 private _HASHED_VERSION;
|
|
bytes32 private constant _TYPE_HASH = keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");
|
|
|
|
/* solhint-enable var-name-mixedcase */
|
|
|
|
/**
|
|
* @dev Initializes the domain separator and parameter caches.
|
|
*
|
|
* The meaning of `name` and `version` is specified in
|
|
* https://eips.ethereum.org/EIPS/eip-712#definition-of-domainseparator[EIP 712]:
|
|
*
|
|
* - `name`: the user readable name of the signing domain, i.e. the name of the DApp or the protocol.
|
|
* - `version`: the current major version of the signing domain.
|
|
*
|
|
* NOTE: These parameters cannot be changed except through a xref:learn::upgrading-smart-contracts.adoc[smart
|
|
* contract upgrade].
|
|
*/
|
|
function __EIP712_init(string memory name, string memory version) internal onlyInitializing {
|
|
__EIP712_init_unchained(name, version);
|
|
}
|
|
|
|
function __EIP712_init_unchained(string memory name, string memory version) internal onlyInitializing {
|
|
bytes32 hashedName = keccak256(bytes(name));
|
|
bytes32 hashedVersion = keccak256(bytes(version));
|
|
_HASHED_NAME = hashedName;
|
|
_HASHED_VERSION = hashedVersion;
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the domain separator for the current chain.
|
|
*/
|
|
function _domainSeparatorV4() internal view returns (bytes32) {
|
|
return _buildDomainSeparator(_TYPE_HASH, _EIP712NameHash(), _EIP712VersionHash());
|
|
}
|
|
|
|
function _buildDomainSeparator(
|
|
bytes32 typeHash,
|
|
bytes32 nameHash,
|
|
bytes32 versionHash
|
|
) private view returns (bytes32) {
|
|
return keccak256(abi.encode(typeHash, nameHash, versionHash, block.chainid, address(this)));
|
|
}
|
|
|
|
/**
|
|
* @dev Given an already https://eips.ethereum.org/EIPS/eip-712#definition-of-hashstruct[hashed struct], this
|
|
* function returns the hash of the fully encoded EIP712 message for this domain.
|
|
*
|
|
* This hash can be used together with {ECDSA-recover} to obtain the signer of a message. For example:
|
|
*
|
|
* ```solidity
|
|
* bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
|
|
* keccak256("Mail(address to,string contents)"),
|
|
* mailTo,
|
|
* keccak256(bytes(mailContents))
|
|
* )));
|
|
* address signer = ECDSA.recover(digest, signature);
|
|
* ```
|
|
*/
|
|
function _hashTypedDataV4(bytes32 structHash) internal view virtual returns (bytes32) {
|
|
return ECDSAUpgradeable.toTypedDataHash(_domainSeparatorV4(), structHash);
|
|
}
|
|
|
|
/**
|
|
* @dev The hash of the name parameter for the EIP712 domain.
|
|
*
|
|
* NOTE: This function reads from storage by default, but can be redefined to return a constant value if gas costs
|
|
* are a concern.
|
|
*/
|
|
function _EIP712NameHash() internal virtual view returns (bytes32) {
|
|
return _HASHED_NAME;
|
|
}
|
|
|
|
/**
|
|
* @dev The hash of the version parameter for the EIP712 domain.
|
|
*
|
|
* NOTE: This function reads from storage by default, but can be redefined to return a constant value if gas costs
|
|
* are a concern.
|
|
*/
|
|
function _EIP712VersionHash() internal virtual view returns (bytes32) {
|
|
return _HASHED_VERSION;
|
|
}
|
|
|
|
/**
|
|
* This empty reserved space is put in place to allow future versions to add new
|
|
* variables without shifting down storage in the inheritance chain.
|
|
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
|
|
*/
|
|
uint256[50] private __gap;
|
|
}
|