be5ed7364b
* Now compiling in a separate directory using truffle 5. * Ported to 0.5.1, now compiling using 0.5.1. * test now also compiles using the truffle 5 hack. * Downgraded to 0.5.0. * Sorted scripts. * Cleaned up the compile script a bit.
61 lines
2.1 KiB
Solidity
61 lines
2.1 KiB
Solidity
pragma solidity ^0.5.0;
|
|
|
|
/**
|
|
* @title Elliptic curve signature operations
|
|
* @dev Based on https://gist.github.com/axic/5b33912c6f61ae6fd96d6c4a47afde6d
|
|
* TODO Remove this library once solidity supports passing a signature to ecrecover.
|
|
* See https://github.com/ethereum/solidity/issues/864
|
|
*/
|
|
|
|
library ECDSA {
|
|
/**
|
|
* @dev Recover signer address from a message by using their signature
|
|
* @param hash bytes32 message, the hash is the signed message. What is recovered is the signer address.
|
|
* @param signature bytes signature, the signature is generated using web3.eth.sign()
|
|
*/
|
|
function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
|
|
bytes32 r;
|
|
bytes32 s;
|
|
uint8 v;
|
|
|
|
// Check the signature length
|
|
if (signature.length != 65) {
|
|
return (address(0));
|
|
}
|
|
|
|
// Divide the signature in r, s and v variables
|
|
// ecrecover takes the signature parameters, and the only way to get them
|
|
// currently is to use assembly.
|
|
// solium-disable-next-line security/no-inline-assembly
|
|
assembly {
|
|
r := mload(add(signature, 0x20))
|
|
s := mload(add(signature, 0x40))
|
|
v := byte(0, mload(add(signature, 0x60)))
|
|
}
|
|
|
|
// Version of signature should be 27 or 28, but 0 and 1 are also possible versions
|
|
if (v < 27) {
|
|
v += 27;
|
|
}
|
|
|
|
// If the version is correct return the signer address
|
|
if (v != 27 && v != 28) {
|
|
return (address(0));
|
|
} else {
|
|
// solium-disable-next-line arg-overflow
|
|
return ecrecover(hash, v, r, s);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* toEthSignedMessageHash
|
|
* @dev prefix a bytes32 value with "\x19Ethereum Signed Message:"
|
|
* and hash the result
|
|
*/
|
|
function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32) {
|
|
// 32 is the length in bytes of hash,
|
|
// enforced by the type signature above
|
|
return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", hash));
|
|
}
|
|
}
|