0f55c18595
* Fix unnamed return variable warning This commit fixes warnings thrown by the solc 0.7.4 compiler: "Warning: Unnamed return variable can remain unassigned. Add an explicit return with value to all non-reverting code paths or name the variable." * Fix function state mutability warning This commit fixes warnings thrown by the solc 0.7.4 compiler: "Warning: Function state mutability can be restricted to pure" * Fix shadows an existing declaration warning This commit fixes warnings thrown by the solc 0.7.4 compiler: "Warning: This declaration shadows an existing declaration." 1. Arguments by default are not underscored. 2. If the name isn't available due to shadowing, use prefix underscore. 3. If prefix underscore isn't available due to shadowing, use suffix underscore.
94 lines
2.9 KiB
Solidity
94 lines
2.9 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
|
|
pragma solidity ^0.7.0;
|
|
|
|
import "./ConditionalEscrow.sol";
|
|
|
|
/**
|
|
* @title RefundEscrow
|
|
* @dev Escrow that holds funds for a beneficiary, deposited from multiple
|
|
* parties.
|
|
* @dev Intended usage: See {Escrow}. Same usage guidelines apply here.
|
|
* @dev The owner account (that is, the contract that instantiates this
|
|
* contract) may deposit, close the deposit period, and allow for either
|
|
* withdrawal by the beneficiary, or refunds to the depositors. All interactions
|
|
* with `RefundEscrow` will be made through the owner contract.
|
|
*/
|
|
contract RefundEscrow is ConditionalEscrow {
|
|
enum State { Active, Refunding, Closed }
|
|
|
|
event RefundsClosed();
|
|
event RefundsEnabled();
|
|
|
|
State private _state;
|
|
address payable private _beneficiary;
|
|
|
|
/**
|
|
* @dev Constructor.
|
|
* @param beneficiary_ The beneficiary of the deposits.
|
|
*/
|
|
constructor (address payable beneficiary_) {
|
|
require(beneficiary_ != address(0), "RefundEscrow: beneficiary is the zero address");
|
|
_beneficiary = beneficiary_;
|
|
_state = State.Active;
|
|
}
|
|
|
|
/**
|
|
* @return The current state of the escrow.
|
|
*/
|
|
function state() public view returns (State) {
|
|
return _state;
|
|
}
|
|
|
|
/**
|
|
* @return The beneficiary of the escrow.
|
|
*/
|
|
function beneficiary() public view returns (address) {
|
|
return _beneficiary;
|
|
}
|
|
|
|
/**
|
|
* @dev Stores funds that may later be refunded.
|
|
* @param refundee The address funds will be sent to if a refund occurs.
|
|
*/
|
|
function deposit(address refundee) public payable virtual override {
|
|
require(_state == State.Active, "RefundEscrow: can only deposit while active");
|
|
super.deposit(refundee);
|
|
}
|
|
|
|
/**
|
|
* @dev Allows for the beneficiary to withdraw their funds, rejecting
|
|
* further deposits.
|
|
*/
|
|
function close() public onlyOwner virtual {
|
|
require(_state == State.Active, "RefundEscrow: can only close while active");
|
|
_state = State.Closed;
|
|
emit RefundsClosed();
|
|
}
|
|
|
|
/**
|
|
* @dev Allows for refunds to take place, rejecting further deposits.
|
|
*/
|
|
function enableRefunds() public onlyOwner virtual {
|
|
require(_state == State.Active, "RefundEscrow: can only enable refunds while active");
|
|
_state = State.Refunding;
|
|
emit RefundsEnabled();
|
|
}
|
|
|
|
/**
|
|
* @dev Withdraws the beneficiary's funds.
|
|
*/
|
|
function beneficiaryWithdraw() public virtual {
|
|
require(_state == State.Closed, "RefundEscrow: beneficiary can only withdraw while closed");
|
|
_beneficiary.transfer(address(this).balance);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns whether refundees can withdraw their deposits (be refunded). The overridden function receives a
|
|
* 'payee' argument, but we ignore it here since the condition is global, not per-payee.
|
|
*/
|
|
function withdrawalAllowed(address) public view override returns (bool) {
|
|
return _state == State.Refunding;
|
|
}
|
|
}
|