3682c6575c
* Error handling in ERC20 and ERC721 * Added message string for require. * Fixed solhint errors. * Updated PR as per issue #1709 * changes as per #1709 and openzeppelin forum. * Changes in require statement * Changes in require statement * build pipeline fix * Changes as per @nventuro's comment. * Update revert reason strings. * Fianal update of revert reason strings. * WIP: Updating reason strings in test cases * WIP: Added changes to ERC20 and ERC721 * Fixes linting errors in *.tes.js files * Achieved 100% code coverage * Updated the test cases with shouldFail.reverting.withMessage() * Fix package-lock. * address review comments * fix linter issues * fix remaining revert reasons
44 lines
1.1 KiB
Solidity
44 lines
1.1 KiB
Solidity
pragma solidity ^0.5.7;
|
|
|
|
import "./IERC165.sol";
|
|
|
|
/**
|
|
* @title ERC165
|
|
* @author Matt Condon (@shrugs)
|
|
* @dev Implements ERC165 using a lookup table.
|
|
*/
|
|
contract ERC165 is IERC165 {
|
|
/*
|
|
* bytes4(keccak256('supportsInterface(bytes4)')) == 0x01ffc9a7
|
|
*/
|
|
bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;
|
|
|
|
/**
|
|
* @dev Mapping of interface ids to whether or not it's supported.
|
|
*/
|
|
mapping(bytes4 => bool) private _supportedInterfaces;
|
|
|
|
/**
|
|
* @dev A contract implementing SupportsInterfaceWithLookup
|
|
* implements ERC165 itself.
|
|
*/
|
|
constructor () internal {
|
|
_registerInterface(_INTERFACE_ID_ERC165);
|
|
}
|
|
|
|
/**
|
|
* @dev Implement supportsInterface(bytes4) using a lookup table.
|
|
*/
|
|
function supportsInterface(bytes4 interfaceId) external view returns (bool) {
|
|
return _supportedInterfaces[interfaceId];
|
|
}
|
|
|
|
/**
|
|
* @dev Internal method for registering an interface.
|
|
*/
|
|
function _registerInterface(bytes4 interfaceId) internal {
|
|
require(interfaceId != 0xffffffff, "ERC165: invalid interface id");
|
|
_supportedInterfaces[interfaceId] = true;
|
|
}
|
|
}
|