2e0713becb
* rename ERC20 to IERC20 * move ERC20.sol to IERC20.sol * rename StandardToken to ERC20 * rename StandardTokenMock to ERC20Mock * move StandardToken.sol to ERC20.sol, likewise test and mock files * rename MintableToken to ERC20Mintable * move MintableToken.sol to ERC20Mintable.sol, likewise test and mock files * rename BurnableToken to ERC20Burnable * move BurnableToken.sol to ERC20Burnable.sol, likewise for related files * rename CappedToken to ERC20Capped * move CappedToken.sol to ERC20Capped.sol, likewise for related files * rename PausableToken to ERC20Pausable * move PausableToken.sol to ERC20Pausable.sol, likewise for related files * rename DetailedERC20 to ERC20Detailed * move DetailedERC20.sol to ERC20Detailed.sol, likewise for related files * rename ERC721 to IERC721, and likewise for other related interfaces * move ERC721.sol to IERC721.sol, likewise for other 721 interfaces * rename ERC721Token to ERC721 * move ERC721Token.sol to ERC721.sol, likewise for related files * rename ERC721BasicToken to ERC721Basic * move ERC721BasicToken.sol to ERC721Basic.sol, likewise for related files * rename ERC721PausableToken to ERC721Pausable * move ERC721PausableToken.sol to ERC721Pausable.sol * rename ERC165 to IERC165 * move ERC165.sol to IERC165.sol * amend comment that ERC20 is based on FirstBlood * fix comments mentioning IERC721Receiver
50 lines
1.1 KiB
Solidity
50 lines
1.1 KiB
Solidity
pragma solidity ^0.4.24;
|
|
|
|
import "./SafeERC20.sol";
|
|
|
|
|
|
/**
|
|
* @title TokenTimelock
|
|
* @dev TokenTimelock is a token holder contract that will allow a
|
|
* beneficiary to extract the tokens after a given release time
|
|
*/
|
|
contract TokenTimelock {
|
|
using SafeERC20 for IERC20;
|
|
|
|
// ERC20 basic token contract being held
|
|
IERC20 public token;
|
|
|
|
// beneficiary of tokens after they are released
|
|
address public beneficiary;
|
|
|
|
// timestamp when token release is enabled
|
|
uint256 public releaseTime;
|
|
|
|
constructor(
|
|
IERC20 _token,
|
|
address _beneficiary,
|
|
uint256 _releaseTime
|
|
)
|
|
public
|
|
{
|
|
// solium-disable-next-line security/no-block-members
|
|
require(_releaseTime > block.timestamp);
|
|
token = _token;
|
|
beneficiary = _beneficiary;
|
|
releaseTime = _releaseTime;
|
|
}
|
|
|
|
/**
|
|
* @notice Transfers tokens held by timelock to beneficiary.
|
|
*/
|
|
function release() public {
|
|
// solium-disable-next-line security/no-block-members
|
|
require(block.timestamp >= releaseTime);
|
|
|
|
uint256 amount = token.balanceOf(address(this));
|
|
require(amount > 0);
|
|
|
|
token.safeTransfer(beneficiary, amount);
|
|
}
|
|
}
|