ad12381549
* update solidity-coverage to ^0.5.0 * update truffle dependency to ^4.1.8 * update solium to ^1.1.7 * update all contracts to solidity ^0.4.23
96 lines
2.3 KiB
Solidity
96 lines
2.3 KiB
Solidity
pragma solidity ^0.4.23;
|
|
|
|
|
|
import "./Ownable.sol";
|
|
import "./rbac/RBAC.sol";
|
|
|
|
|
|
/**
|
|
* @title Whitelist
|
|
* @dev The Whitelist contract has a whitelist of addresses, and provides basic authorization control functions.
|
|
* @dev This simplifies the implementation of "user permissions".
|
|
*/
|
|
contract Whitelist is Ownable, RBAC {
|
|
event WhitelistedAddressAdded(address addr);
|
|
event WhitelistedAddressRemoved(address addr);
|
|
|
|
string public constant ROLE_WHITELISTED = "whitelist";
|
|
|
|
/**
|
|
* @dev Throws if called by any account that's not whitelisted.
|
|
*/
|
|
modifier onlyWhitelisted() {
|
|
checkRole(msg.sender, ROLE_WHITELISTED);
|
|
_;
|
|
}
|
|
|
|
/**
|
|
* @dev add an address to the whitelist
|
|
* @param addr address
|
|
* @return true if the address was added to the whitelist, false if the address was already in the whitelist
|
|
*/
|
|
function addAddressToWhitelist(address addr)
|
|
onlyOwner
|
|
public
|
|
{
|
|
addRole(addr, ROLE_WHITELISTED);
|
|
emit WhitelistedAddressAdded(addr);
|
|
}
|
|
|
|
/**
|
|
* @dev getter to determine if address is in whitelist
|
|
*/
|
|
function whitelist(address addr)
|
|
public
|
|
view
|
|
returns (bool)
|
|
{
|
|
return hasRole(addr, ROLE_WHITELISTED);
|
|
}
|
|
|
|
/**
|
|
* @dev add addresses to the whitelist
|
|
* @param addrs addresses
|
|
* @return true if at least one address was added to the whitelist,
|
|
* false if all addresses were already in the whitelist
|
|
*/
|
|
function addAddressesToWhitelist(address[] addrs)
|
|
onlyOwner
|
|
public
|
|
{
|
|
for (uint256 i = 0; i < addrs.length; i++) {
|
|
addAddressToWhitelist(addrs[i]);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev remove an address from the whitelist
|
|
* @param addr address
|
|
* @return true if the address was removed from the whitelist,
|
|
* false if the address wasn't in the whitelist in the first place
|
|
*/
|
|
function removeAddressFromWhitelist(address addr)
|
|
onlyOwner
|
|
public
|
|
{
|
|
removeRole(addr, ROLE_WHITELISTED);
|
|
emit WhitelistedAddressRemoved(addr);
|
|
}
|
|
|
|
/**
|
|
* @dev remove addresses from the whitelist
|
|
* @param addrs addresses
|
|
* @return true if at least one address was removed from the whitelist,
|
|
* false if all addresses weren't in the whitelist in the first place
|
|
*/
|
|
function removeAddressesFromWhitelist(address[] addrs)
|
|
onlyOwner
|
|
public
|
|
{
|
|
for (uint256 i = 0; i < addrs.length; i++) {
|
|
removeAddressFromWhitelist(addrs[i]);
|
|
}
|
|
}
|
|
|
|
}
|