ef347ffccc
* Consolidted ERC20 Interface and Implementation Files * Fixed CanReclaimToken's tests to use StandardTokenMock instead of BasicTokenMock * Changed token's variable type in TokenTimelock to ERC20 * Merged the StandardBurnableToken with BurnableToken since it now inherits from StandardToken; Fixed TokenTimelock so it uses SafeERC20 for ERC20 * Fixed variable type for _token in TokenTimelock constructor * Fixed linting warning in BurnableToken * Added back burnFrom tests.
50 lines
1.1 KiB
Solidity
50 lines
1.1 KiB
Solidity
pragma solidity ^0.4.24;
|
|
|
|
import "./SafeERC20.sol";
|
|
|
|
|
|
/**
|
|
* @title TokenTimelock
|
|
* @dev TokenTimelock is a token holder contract that will allow a
|
|
* beneficiary to extract the tokens after a given release time
|
|
*/
|
|
contract TokenTimelock {
|
|
using SafeERC20 for ERC20;
|
|
|
|
// ERC20 basic token contract being held
|
|
ERC20 public token;
|
|
|
|
// beneficiary of tokens after they are released
|
|
address public beneficiary;
|
|
|
|
// timestamp when token release is enabled
|
|
uint256 public releaseTime;
|
|
|
|
constructor(
|
|
ERC20 _token,
|
|
address _beneficiary,
|
|
uint256 _releaseTime
|
|
)
|
|
public
|
|
{
|
|
// solium-disable-next-line security/no-block-members
|
|
require(_releaseTime > block.timestamp);
|
|
token = _token;
|
|
beneficiary = _beneficiary;
|
|
releaseTime = _releaseTime;
|
|
}
|
|
|
|
/**
|
|
* @notice Transfers tokens held by timelock to beneficiary.
|
|
*/
|
|
function release() public {
|
|
// solium-disable-next-line security/no-block-members
|
|
require(block.timestamp >= releaseTime);
|
|
|
|
uint256 amount = token.balanceOf(address(this));
|
|
require(amount > 0);
|
|
|
|
token.safeTransfer(beneficiary, amount);
|
|
}
|
|
}
|