443 lines
15 KiB
Solidity
443 lines
15 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC721/ERC721.sol)
|
|
|
|
pragma solidity ^0.8.19;
|
|
|
|
import {IERC721} from "./IERC721.sol";
|
|
import {IERC721Receiver} from "./IERC721Receiver.sol";
|
|
import {IERC721Metadata} from "./extensions/IERC721Metadata.sol";
|
|
import {Context} from "../../utils/Context.sol";
|
|
import {Strings} from "../../utils/Strings.sol";
|
|
import {IERC165, ERC165} from "../../utils/introspection/ERC165.sol";
|
|
import {IERC721Errors} from "../../interfaces/draft-IERC6093.sol";
|
|
|
|
/**
|
|
* @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
|
|
* the Metadata extension, but not including the Enumerable extension, which is available separately as
|
|
* {ERC721Enumerable}.
|
|
*/
|
|
abstract contract ERC721 is Context, ERC165, IERC721, IERC721Metadata, IERC721Errors {
|
|
using Strings for uint256;
|
|
|
|
// Token name
|
|
string private _name;
|
|
|
|
// Token symbol
|
|
string private _symbol;
|
|
|
|
// Mapping from token ID to owner address
|
|
mapping(uint256 => address) private _owners;
|
|
|
|
// Mapping owner address to token count
|
|
mapping(address => uint256) private _balances;
|
|
|
|
// Mapping from token ID to approved address
|
|
mapping(uint256 => address) private _tokenApprovals;
|
|
|
|
// Mapping from owner to operator approvals
|
|
mapping(address => mapping(address => bool)) private _operatorApprovals;
|
|
|
|
/**
|
|
* @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
|
|
*/
|
|
constructor(string memory name_, string memory symbol_) {
|
|
_name = name_;
|
|
_symbol = symbol_;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC165-supportsInterface}.
|
|
*/
|
|
function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
|
|
return
|
|
interfaceId == type(IERC721).interfaceId ||
|
|
interfaceId == type(IERC721Metadata).interfaceId ||
|
|
super.supportsInterface(interfaceId);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-balanceOf}.
|
|
*/
|
|
function balanceOf(address owner) public view virtual returns (uint256) {
|
|
if (owner == address(0)) {
|
|
revert ERC721InvalidOwner(address(0));
|
|
}
|
|
return _balances[owner];
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-ownerOf}.
|
|
*/
|
|
function ownerOf(uint256 tokenId) public view virtual returns (address) {
|
|
address owner = _ownerOf(tokenId);
|
|
if (owner == address(0)) {
|
|
revert ERC721NonexistentToken(tokenId);
|
|
}
|
|
return owner;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721Metadata-name}.
|
|
*/
|
|
function name() public view virtual returns (string memory) {
|
|
return _name;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721Metadata-symbol}.
|
|
*/
|
|
function symbol() public view virtual returns (string memory) {
|
|
return _symbol;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721Metadata-tokenURI}.
|
|
*/
|
|
function tokenURI(uint256 tokenId) public view virtual returns (string memory) {
|
|
_requireMinted(tokenId);
|
|
|
|
string memory baseURI = _baseURI();
|
|
return bytes(baseURI).length > 0 ? string.concat(baseURI, tokenId.toString()) : "";
|
|
}
|
|
|
|
/**
|
|
* @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
|
|
* token will be the concatenation of the `baseURI` and the `tokenId`. Empty
|
|
* by default, can be overridden in child contracts.
|
|
*/
|
|
function _baseURI() internal view virtual returns (string memory) {
|
|
return "";
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-approve}.
|
|
*/
|
|
function approve(address to, uint256 tokenId) public virtual {
|
|
address owner = ownerOf(tokenId);
|
|
if (to == owner) {
|
|
revert ERC721InvalidOperator(owner);
|
|
}
|
|
|
|
if (_msgSender() != owner && !isApprovedForAll(owner, _msgSender())) {
|
|
revert ERC721InvalidApprover(_msgSender());
|
|
}
|
|
|
|
_approve(to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-getApproved}.
|
|
*/
|
|
function getApproved(uint256 tokenId) public view virtual returns (address) {
|
|
_requireMinted(tokenId);
|
|
|
|
return _tokenApprovals[tokenId];
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-setApprovalForAll}.
|
|
*/
|
|
function setApprovalForAll(address operator, bool approved) public virtual {
|
|
_setApprovalForAll(_msgSender(), operator, approved);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-isApprovedForAll}.
|
|
*/
|
|
function isApprovedForAll(address owner, address operator) public view virtual returns (bool) {
|
|
return _operatorApprovals[owner][operator];
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-transferFrom}.
|
|
*/
|
|
function transferFrom(address from, address to, uint256 tokenId) public virtual {
|
|
if (to == address(0)) {
|
|
revert ERC721InvalidReceiver(address(0));
|
|
}
|
|
address owner = _update(to, tokenId, _msgSender());
|
|
if (owner == address(0)) {
|
|
revert ERC721NonexistentToken(tokenId);
|
|
} else if (owner != from) {
|
|
revert ERC721IncorrectOwner(from, tokenId, owner);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-safeTransferFrom}.
|
|
*/
|
|
function safeTransferFrom(address from, address to, uint256 tokenId) public virtual {
|
|
safeTransferFrom(from, to, tokenId, "");
|
|
}
|
|
|
|
/**
|
|
* @dev See {IERC721-safeTransferFrom}.
|
|
*/
|
|
function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public virtual {
|
|
transferFrom(from, to, tokenId);
|
|
_checkOnERC721Received(from, to, tokenId, data);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
|
|
*/
|
|
function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
|
|
return _owners[tokenId];
|
|
}
|
|
|
|
/**
|
|
* @dev Returns whether `tokenId` exists.
|
|
*
|
|
* Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
|
|
*
|
|
* Tokens start existing when they are minted (`_mint`),
|
|
* and stop existing when they are burned (`_burn`).
|
|
*/
|
|
function _exists(uint256 tokenId) internal view virtual returns (bool) {
|
|
return _ownerOf(tokenId) != address(0);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns whether `spender` is allowed to manage `owner`'s tokens, or `tokenId` in
|
|
* particular (ignoring whether it is owned by `owner`).
|
|
*
|
|
* WARNING:
|
|
* - ownership is not checked.
|
|
* - spender = address(0) will lead to this function returning true in unexpected situations.
|
|
*/
|
|
function _isApproved(address owner, address spender, uint256 tokenId) internal view virtual returns (bool) {
|
|
return owner == spender || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender;
|
|
}
|
|
|
|
/**
|
|
* @dev Checks whether `spender` was approved by `owner` to operate on `tokenId` or is the owner of `tokenId`.
|
|
* Reverts if `spender` is not approved nor owner of `tokenId`.
|
|
*
|
|
* WARNING:
|
|
* - ownership is not checked.
|
|
*/
|
|
function _checkApproved(address owner, address spender, uint256 tokenId) internal view virtual {
|
|
if (!_isApproved(owner, spender, tokenId)) {
|
|
revert ERC721InsufficientApproval(spender, tokenId);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Transfers `tokenId` from its current owner to `to`, or alternatively mints (or burns) if the current owner
|
|
* (or `to`) is the zero address. Returns the owner of the `tokenId` before the update.
|
|
*
|
|
* The `operatorCheck` argument is optional. If the value passed is non 0, then this function will check that
|
|
* `operatorCheck` is either the owner of the token, or approved to operate on the token (by the owner).
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _update(address to, uint256 tokenId, address operatorCheck) internal virtual returns (address) {
|
|
address from = _ownerOf(tokenId);
|
|
|
|
// Perform (optional) operator check
|
|
if (operatorCheck != address(0)) {
|
|
_checkApproved(from, operatorCheck, tokenId);
|
|
}
|
|
|
|
// Execute the update
|
|
if (from != address(0)) {
|
|
delete _tokenApprovals[tokenId];
|
|
unchecked {
|
|
_balances[from] -= 1;
|
|
}
|
|
}
|
|
|
|
if (to != address(0)) {
|
|
unchecked {
|
|
_balances[to] += 1;
|
|
}
|
|
}
|
|
|
|
_owners[tokenId] = to;
|
|
|
|
emit Transfer(from, to, tokenId);
|
|
|
|
return from;
|
|
}
|
|
|
|
/**
|
|
* @dev Mints `tokenId` and transfers it to `to`.
|
|
*
|
|
* WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `tokenId` must not exist.
|
|
* - `to` cannot be the zero address.
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _mint(address to, uint256 tokenId) internal {
|
|
if (to == address(0)) {
|
|
revert ERC721InvalidReceiver(address(0));
|
|
}
|
|
address from = _update(to, tokenId, address(0));
|
|
if (from != address(0)) {
|
|
revert ERC721InvalidSender(address(0));
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Safely mints `tokenId` and transfers it to `to`.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `tokenId` must not exist.
|
|
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _safeMint(address to, uint256 tokenId) internal virtual {
|
|
_safeMint(to, tokenId, "");
|
|
}
|
|
|
|
/**
|
|
* @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
|
|
* forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
|
|
*/
|
|
function _safeMint(address to, uint256 tokenId, bytes memory data) internal virtual {
|
|
_mint(to, tokenId);
|
|
_checkOnERC721Received(address(0), to, tokenId, data);
|
|
}
|
|
|
|
/**
|
|
* @dev Destroys `tokenId`.
|
|
* The approval is cleared when the token is burned.
|
|
* This is an internal function that does not check if the sender is authorized to operate on the token.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `tokenId` must exist.
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _burn(uint256 tokenId) internal {
|
|
address from = _update(address(0), tokenId, address(0));
|
|
if (from == address(0)) {
|
|
revert ERC721NonexistentToken(tokenId);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Transfers `tokenId` from `from` to `to`.
|
|
* As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `to` cannot be the zero address.
|
|
* - `tokenId` token must be owned by `from`.
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _transfer(address from, address to, uint256 tokenId) internal {
|
|
if (to == address(0)) {
|
|
revert ERC721InvalidReceiver(address(0));
|
|
}
|
|
address owner = _update(to, tokenId, address(0));
|
|
if (owner == address(0)) {
|
|
revert ERC721NonexistentToken(tokenId);
|
|
} else if (owner != from) {
|
|
revert ERC721IncorrectOwner(from, tokenId, owner);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
|
|
* are aware of the ERC721 protocol to prevent tokens from being forever locked.
|
|
*
|
|
* `data` is additional data, it has no specified format and it is sent in call to `to`.
|
|
*
|
|
* This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
|
|
* implement alternative mechanisms to perform token transfer, such as signature-based.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `from` cannot be the zero address.
|
|
* - `to` cannot be the zero address.
|
|
* - `tokenId` token must exist and be owned by `from`.
|
|
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
|
|
*
|
|
* Emits a {Transfer} event.
|
|
*/
|
|
function _safeTransfer(address from, address to, uint256 tokenId, bytes memory data) internal virtual {
|
|
_transfer(from, to, tokenId);
|
|
_checkOnERC721Received(from, to, tokenId, data);
|
|
}
|
|
|
|
/**
|
|
* @dev Approve `to` to operate on `tokenId`
|
|
*
|
|
* Emits an {Approval} event.
|
|
*/
|
|
function _approve(address to, uint256 tokenId) internal virtual {
|
|
_tokenApprovals[tokenId] = to;
|
|
emit Approval(ownerOf(tokenId), to, tokenId);
|
|
}
|
|
|
|
/**
|
|
* @dev Approve `operator` to operate on all of `owner` tokens
|
|
*
|
|
* Emits an {ApprovalForAll} event.
|
|
*/
|
|
function _setApprovalForAll(address owner, address operator, bool approved) internal virtual {
|
|
if (owner == operator) {
|
|
revert ERC721InvalidOperator(owner);
|
|
}
|
|
_operatorApprovals[owner][operator] = approved;
|
|
emit ApprovalForAll(owner, operator, approved);
|
|
}
|
|
|
|
/**
|
|
* @dev Reverts if the `tokenId` has not been minted yet.
|
|
*/
|
|
function _requireMinted(uint256 tokenId) internal view virtual {
|
|
if (!_exists(tokenId)) {
|
|
revert ERC721NonexistentToken(tokenId);
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Private function to invoke {IERC721Receiver-onERC721Received} on a target address. This will revert if the
|
|
* recipient doesn't accept the token transfer. The call is not executed if the target address is not a contract.
|
|
*
|
|
* @param from address representing the previous owner of the given token ID
|
|
* @param to target address that will receive the tokens
|
|
* @param tokenId uint256 ID of the token to be transferred
|
|
* @param data bytes optional data to send along with the call
|
|
*/
|
|
function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory data) private {
|
|
if (to.code.length > 0) {
|
|
try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
|
|
if (retval != IERC721Receiver.onERC721Received.selector) {
|
|
revert ERC721InvalidReceiver(to);
|
|
}
|
|
} catch (bytes memory reason) {
|
|
if (reason.length == 0) {
|
|
revert ERC721InvalidReceiver(to);
|
|
} else {
|
|
/// @solidity memory-safe-assembly
|
|
assembly {
|
|
revert(add(32, reason), mload(reason))
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
/**
|
|
* @dev Unsafe write access to the balances, used by extensions that "mint" tokens using an {ownerOf} override.
|
|
*
|
|
* WARNING: Anyone calling this MUST ensure that the balances remain consistent with the ownership. The invariant
|
|
* being that for any address `a` the value returned by `balanceOf(a)` must be equal to the number of tokens such
|
|
* that `ownerOf(tokenId)` is `a`.
|
|
*/
|
|
function _increaseBalance(address account, uint256 value) internal virtual {
|
|
_balances[account] += value;
|
|
}
|
|
}
|