65 lines
2.5 KiB
Solidity
65 lines
2.5 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/ERC20Wrapper.sol)
|
|
|
|
pragma solidity ^0.8.0;
|
|
|
|
import "../ERC20Upgradeable.sol";
|
|
import "../utils/SafeERC20Upgradeable.sol";
|
|
import "../../../proxy/utils/Initializable.sol";
|
|
|
|
/**
|
|
* @dev Extension of the ERC20 token contract to support token wrapping.
|
|
*
|
|
* Users can deposit and withdraw "underlying tokens" and receive a matching number of "wrapped tokens". This is useful
|
|
* in conjunction with other modules. For example, combining this wrapping mechanism with {ERC20Votes} will allow the
|
|
* wrapping of an existing "basic" ERC20 into a governance token.
|
|
*
|
|
* _Available since v4.2._
|
|
*/
|
|
abstract contract ERC20WrapperUpgradeable is Initializable, ERC20Upgradeable {
|
|
IERC20Upgradeable public underlying;
|
|
|
|
function __ERC20Wrapper_init(IERC20Upgradeable underlyingToken) internal onlyInitializing {
|
|
__ERC20Wrapper_init_unchained(underlyingToken);
|
|
}
|
|
|
|
function __ERC20Wrapper_init_unchained(IERC20Upgradeable underlyingToken) internal onlyInitializing {
|
|
underlying = underlyingToken;
|
|
}
|
|
|
|
/**
|
|
* @dev Allow a user to deposit underlying tokens and mint the corresponding number of wrapped tokens.
|
|
*/
|
|
function depositFor(address account, uint256 amount) public virtual returns (bool) {
|
|
SafeERC20Upgradeable.safeTransferFrom(underlying, _msgSender(), address(this), amount);
|
|
_mint(account, amount);
|
|
return true;
|
|
}
|
|
|
|
/**
|
|
* @dev Allow a user to burn a number of wrapped tokens and withdraw the corresponding number of underlying tokens.
|
|
*/
|
|
function withdrawTo(address account, uint256 amount) public virtual returns (bool) {
|
|
_burn(_msgSender(), amount);
|
|
SafeERC20Upgradeable.safeTransfer(underlying, account, amount);
|
|
return true;
|
|
}
|
|
|
|
/**
|
|
* @dev Mint wrapped token to cover any underlyingTokens that would have been transfered by mistake. Internal
|
|
* function that can be exposed with access control if desired.
|
|
*/
|
|
function _recover(address account) internal virtual returns (uint256) {
|
|
uint256 value = underlying.balanceOf(address(this)) - totalSupply();
|
|
_mint(account, value);
|
|
return value;
|
|
}
|
|
|
|
/**
|
|
* @dev This empty reserved space is put in place to allow future versions to add new
|
|
* variables without shifting down storage in the inheritance chain.
|
|
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
|
|
*/
|
|
uint256[50] private __gap;
|
|
}
|