5dfe7215a9
* Initial migration to Solidity 0.6.x - v3.0 first steps (#2063) * Initial migration, missing GSN, 721, 777 and Crowdsales. * Add _beforeTokenOperation and _afterTokenOperation. * Add documentation for hooks. * Add hooks doc * Add missing drafts * Add back ERC721 with hooks * Bring back ERC777 * Notes on hooks * Bring back GSN * Make functions virtual * Make GSN overrides explicit * Fix ERC20Pausable tests * Remove virtual from some view functions * Update linter * Delete examples * Remove unnecessary virtual * Remove roles from Pausable * Remove roles * Remove users of roles * Adapt ERC20 tests * Fix ERC721 tests * Add all ERC721 hooks * Add ERC777 hooks * Fix remaining tests * Bump compiler version * Move 721BurnableMock into mocks directory * Remove _before hooks * Fix tests * Upgrade linter * Put modifiers last * Remove _beforeTokenApproval and _beforeOperatorApproval hooks
93 lines
3.0 KiB
Solidity
93 lines
3.0 KiB
Solidity
pragma solidity ^0.6.0;
|
||
|
||
import "./ConditionalEscrow.sol";
|
||
|
||
/**
|
||
* @title RefundEscrow
|
||
* @dev Escrow that holds funds for a beneficiary, deposited from multiple
|
||
* parties.
|
||
* @dev Intended usage: See {Escrow}. Same usage guidelines apply here.
|
||
* @dev The primary account (that is, the contract that instantiates this
|
||
* contract) may deposit, close the deposit period, and allow for either
|
||
* withdrawal by the beneficiary, or refunds to the depositors. All interactions
|
||
* with `RefundEscrow` will be made through the primary contract. See the
|
||
* `RefundableCrowdsale` contract for an example of `RefundEscrow`’s use.
|
||
*/
|
||
contract RefundEscrow is ConditionalEscrow {
|
||
enum State { Active, Refunding, Closed }
|
||
|
||
event RefundsClosed();
|
||
event RefundsEnabled();
|
||
|
||
State private _state;
|
||
address payable private _beneficiary;
|
||
|
||
/**
|
||
* @dev Constructor.
|
||
* @param beneficiary The beneficiary of the deposits.
|
||
*/
|
||
constructor (address payable beneficiary) public {
|
||
require(beneficiary != address(0), "RefundEscrow: beneficiary is the zero address");
|
||
_beneficiary = beneficiary;
|
||
_state = State.Active;
|
||
}
|
||
|
||
/**
|
||
* @return The current state of the escrow.
|
||
*/
|
||
function state() public view returns (State) {
|
||
return _state;
|
||
}
|
||
|
||
/**
|
||
* @return The beneficiary of the escrow.
|
||
*/
|
||
function beneficiary() public view returns (address) {
|
||
return _beneficiary;
|
||
}
|
||
|
||
/**
|
||
* @dev Stores funds that may later be refunded.
|
||
* @param refundee The address funds will be sent to if a refund occurs.
|
||
*/
|
||
function deposit(address refundee) public payable virtual override {
|
||
require(_state == State.Active, "RefundEscrow: can only deposit while active");
|
||
super.deposit(refundee);
|
||
}
|
||
|
||
/**
|
||
* @dev Allows for the beneficiary to withdraw their funds, rejecting
|
||
* further deposits.
|
||
*/
|
||
function close() public onlyPrimary virtual {
|
||
require(_state == State.Active, "RefundEscrow: can only close while active");
|
||
_state = State.Closed;
|
||
emit RefundsClosed();
|
||
}
|
||
|
||
/**
|
||
* @dev Allows for refunds to take place, rejecting further deposits.
|
||
*/
|
||
function enableRefunds() public onlyPrimary virtual {
|
||
require(_state == State.Active, "RefundEscrow: can only enable refunds while active");
|
||
_state = State.Refunding;
|
||
emit RefundsEnabled();
|
||
}
|
||
|
||
/**
|
||
* @dev Withdraws the beneficiary's funds.
|
||
*/
|
||
function beneficiaryWithdraw() public virtual {
|
||
require(_state == State.Closed, "RefundEscrow: beneficiary can only withdraw while closed");
|
||
_beneficiary.transfer(address(this).balance);
|
||
}
|
||
|
||
/**
|
||
* @dev Returns whether refundees can withdraw their deposits (be refunded). The overridden function receives a
|
||
* 'payee' argument, but we ignore it here since the condition is global, not per-payee.
|
||
*/
|
||
function withdrawalAllowed(address) public view override returns (bool) {
|
||
return _state == State.Refunding;
|
||
}
|
||
}
|