5dfe7215a9
* Initial migration to Solidity 0.6.x - v3.0 first steps (#2063) * Initial migration, missing GSN, 721, 777 and Crowdsales. * Add _beforeTokenOperation and _afterTokenOperation. * Add documentation for hooks. * Add hooks doc * Add missing drafts * Add back ERC721 with hooks * Bring back ERC777 * Notes on hooks * Bring back GSN * Make functions virtual * Make GSN overrides explicit * Fix ERC20Pausable tests * Remove virtual from some view functions * Update linter * Delete examples * Remove unnecessary virtual * Remove roles from Pausable * Remove roles * Remove users of roles * Adapt ERC20 tests * Fix ERC721 tests * Add all ERC721 hooks * Add ERC777 hooks * Fix remaining tests * Bump compiler version * Move 721BurnableMock into mocks directory * Remove _before hooks * Fix tests * Upgrade linter * Put modifiers last * Remove _beforeTokenApproval and _beforeOperatorApproval hooks
84 lines
2.8 KiB
Solidity
84 lines
2.8 KiB
Solidity
pragma solidity ^0.6.0;
|
|
|
|
import "../../math/SafeMath.sol";
|
|
import "../../ownership/Secondary.sol";
|
|
import "../../utils/Address.sol";
|
|
|
|
/**
|
|
* @title Escrow
|
|
* @dev Base escrow contract, holds funds designated for a payee until they
|
|
* withdraw them.
|
|
*
|
|
* Intended usage: This contract (and derived escrow contracts) should be a
|
|
* standalone contract, that only interacts with the contract that instantiated
|
|
* it. That way, it is guaranteed that all Ether will be handled according to
|
|
* the `Escrow` rules, and there is no need to check for payable functions or
|
|
* transfers in the inheritance tree. The contract that uses the escrow as its
|
|
* payment method should be its primary, and provide public methods redirecting
|
|
* to the escrow's deposit and withdraw.
|
|
*/
|
|
contract Escrow is Secondary {
|
|
using SafeMath for uint256;
|
|
using Address for address payable;
|
|
|
|
event Deposited(address indexed payee, uint256 weiAmount);
|
|
event Withdrawn(address indexed payee, uint256 weiAmount);
|
|
|
|
mapping(address => uint256) private _deposits;
|
|
|
|
function depositsOf(address payee) public view returns (uint256) {
|
|
return _deposits[payee];
|
|
}
|
|
|
|
/**
|
|
* @dev Stores the sent amount as credit to be withdrawn.
|
|
* @param payee The destination address of the funds.
|
|
*/
|
|
function deposit(address payee) public virtual payable onlyPrimary {
|
|
uint256 amount = msg.value;
|
|
_deposits[payee] = _deposits[payee].add(amount);
|
|
|
|
emit Deposited(payee, amount);
|
|
}
|
|
|
|
/**
|
|
* @dev Withdraw accumulated balance for a payee, forwarding 2300 gas (a
|
|
* Solidity `transfer`).
|
|
*
|
|
* NOTE: This function has been deprecated, use {withdrawWithGas} instead.
|
|
* Calling contracts with fixed-gas limits is an anti-pattern and may break
|
|
* contract interactions in network upgrades (hardforks).
|
|
* https://diligence.consensys.net/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more.]
|
|
*
|
|
* @param payee The address whose funds will be withdrawn and transferred to.
|
|
*/
|
|
function withdraw(address payable payee) public virtual onlyPrimary {
|
|
uint256 payment = _deposits[payee];
|
|
|
|
_deposits[payee] = 0;
|
|
|
|
payee.transfer(payment);
|
|
|
|
emit Withdrawn(payee, payment);
|
|
}
|
|
|
|
/**
|
|
* @dev Same as {withdraw}, but forwarding all gas to the recipient.
|
|
*
|
|
* WARNING: Forwarding all gas opens the door to reentrancy vulnerabilities.
|
|
* Make sure you trust the recipient, or are either following the
|
|
* checks-effects-interactions pattern or using {ReentrancyGuard}.
|
|
*
|
|
* _Available since v2.4.0._
|
|
*/
|
|
function withdrawWithGas(address payable payee) public virtual onlyPrimary {
|
|
uint256 payment = _deposits[payee];
|
|
|
|
_deposits[payee] = 0;
|
|
|
|
payee.sendValue(payment);
|
|
|
|
emit Withdrawn(payee, payment);
|
|
}
|
|
}
|