b7d60f2f9a
* Bump required compiler version to 0.5.2. * Fix shadowed variable warning in ERC20Migrator. * Rename Counter to Counters. * Add dummy state variable to SafeERC20Helper. * Update changelog entry. * Fix CountersImpl name. * Improve changelog entry.
45 lines
1.1 KiB
Solidity
45 lines
1.1 KiB
Solidity
pragma solidity ^0.5.2;
|
|
|
|
import "./IERC165.sol";
|
|
|
|
/**
|
|
* @title ERC165
|
|
* @author Matt Condon (@shrugs)
|
|
* @dev Implements ERC165 using a lookup table.
|
|
*/
|
|
contract ERC165 is IERC165 {
|
|
bytes4 private constant _INTERFACE_ID_ERC165 = 0x01ffc9a7;
|
|
/**
|
|
* 0x01ffc9a7 ===
|
|
* bytes4(keccak256('supportsInterface(bytes4)'))
|
|
*/
|
|
|
|
/**
|
|
* @dev a mapping of interface id to whether or not it's supported
|
|
*/
|
|
mapping(bytes4 => bool) private _supportedInterfaces;
|
|
|
|
/**
|
|
* @dev A contract implementing SupportsInterfaceWithLookup
|
|
* implement ERC165 itself
|
|
*/
|
|
constructor () internal {
|
|
_registerInterface(_INTERFACE_ID_ERC165);
|
|
}
|
|
|
|
/**
|
|
* @dev implement supportsInterface(bytes4) using a lookup table
|
|
*/
|
|
function supportsInterface(bytes4 interfaceId) external view returns (bool) {
|
|
return _supportedInterfaces[interfaceId];
|
|
}
|
|
|
|
/**
|
|
* @dev internal method for registering an interface
|
|
*/
|
|
function _registerInterface(bytes4 interfaceId) internal {
|
|
require(interfaceId != 0xffffffff);
|
|
_supportedInterfaces[interfaceId] = true;
|
|
}
|
|
}
|