From 788d6a129a342d7a23a91ad553479e861845a9b2 Mon Sep 17 00:00:00 2001
From: Francisco <fg@frang.io>
Date: Wed, 12 Apr 2023 12:09:30 -0300
Subject: [PATCH] Add fuzz tests for ShortString (#4175)

---
 test/utils/ShortStrings.t.sol | 55 +++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 test/utils/ShortStrings.t.sol

diff --git a/test/utils/ShortStrings.t.sol b/test/utils/ShortStrings.t.sol
new file mode 100644
index 000000000..7c4faa89d
--- /dev/null
+++ b/test/utils/ShortStrings.t.sol
@@ -0,0 +1,55 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.0;
+
+import "forge-std/Test.sol";
+
+import "../../contracts/utils/ShortStrings.sol";
+
+contract ShortStringsTest is Test {
+    string _fallback;
+
+    function testRoundtripShort(string memory input) external {
+        vm.assume(_isShort(input));
+        ShortString short = ShortStrings.toShortString(input);
+        string memory output = ShortStrings.toString(short);
+        assertEq(input, output);
+    }
+
+    function testRoundtripWithFallback(string memory input, string memory fallbackInitial) external {
+        _fallback = fallbackInitial; // Make sure that the initial value has no effect
+        ShortString short = ShortStrings.toShortStringWithFallback(input, _fallback);
+        string memory output = ShortStrings.toStringWithFallback(short, _fallback);
+        assertEq(input, output);
+    }
+
+    function testRevertLong(string memory input) external {
+        vm.assume(!_isShort(input));
+        vm.expectRevert(abi.encodeWithSelector(ShortStrings.StringTooLong.selector, input));
+        this.toShortString(input);
+    }
+
+    function testLengthShort(string memory input) external {
+        vm.assume(_isShort(input));
+        uint256 inputLength = bytes(input).length;
+        ShortString short = ShortStrings.toShortString(input);
+        uint256 shortLength = ShortStrings.byteLength(short);
+        assertEq(inputLength, shortLength);
+    }
+
+    function testLengthWithFallback(string memory input, string memory fallbackInitial) external {
+        _fallback = fallbackInitial;
+        uint256 inputLength = bytes(input).length;
+        ShortString short = ShortStrings.toShortStringWithFallback(input, _fallback);
+        uint256 shortLength = ShortStrings.byteLengthWithFallback(short, _fallback);
+        assertEq(inputLength, shortLength);
+    }
+
+    function toShortString(string memory input) external pure returns (ShortString) {
+        return ShortStrings.toShortString(input);
+    }
+
+    function _isShort(string memory input) internal pure returns (bool) {
+        return bytes(input).length < 32;
+    }
+}